如何将chatgpt整合到word中-kb88凯时官网登录

目录

• 引言
• 需求
• 实现
• 1. api模型选择和费率
• 2.代码
  • 2.1.准备工作
  • 2.2. 调用api
  • 2.3.提取信息
  • 2.4.计算模型使用费用
  • 2.5.返回信息到word界面
• 3.界面
• 4.实际使用效果

引言

自chatgpt出现，各种基于它的软件扩展纷至沓来，目前word支持chatgpt的add-in有两款，可以通过:

插入->获取加载项->搜索openai查看。

其中ghostwriter从介绍上看功能比较单一，而且软件需要购买，用自己的api-key，意味着调用api还要单独出钱。

第二个，软件似乎是免费的，应该也是用自己的api-key。从介绍的视频上看符合使用的预期，可以发送选取的文字到chatgpt，并结合预设的prompt信息返回所需功能，但是安全性未知。

这类软件实际上是将内容发送到openai的服务器，并将获取返回内容呈现，于是产生了使用vba在word中整合chatgpt的想法。虽然使用其他语言(比如python)调用api更加方便快捷，但vba对内容的操作更直接。

需求

使用chatgpt修改语言时，需要将文本复制到网页版的chatgpt中。省掉复制粘贴的过程，能提升效率。设想有以下需求：

基本需求（已实现）

• 对选取的文字进行操作，包括修改语言，翻译，检查语法错误等
• 可以选择不同的模型
• 用自己的api-key
• token数目显示和计费

进阶需求（已放弃）

• 提供add-in安装或者可分享
• 自定义ribbon的图标
• 增加ribbon下拉菜单，实现用户选择模型类型
• 增加ribbon选项，实现用户提交api-key

作为野生程序猿，花了一下午完成基本需求，进阶的内容只要花时间是可以实现的。不过相信微软的攻城狮正在全力将chatgpt的功能整合到office全家桶中。类似这样个人级别的应用，最终会被微软发布的新功能淘汰，因此无意投入过多。此项目作为vba练手，基本需求已满足，也可以作为微软发布新word前的过渡。

实现

一切的前提是有openai的账号并且绑定了付款方式。新注册的账号有$18自动到账，因此无需绑定付款方式也可以调用。用完之后再决定需不需要单独为此付费。

1. api模型选择和费率

费用如下，是按照1k token来算的，可以简单理解为字数，但不完全相同。最新的模型是davinci，收费也是最高的。注意这里的token数量指的是发送和返回的token的总和。chatgpt告诉我6000字的文章，按照常规算法，会有10w的token。。好像还是网页版香呀。。

具体调用中，使用模型名称如下。

他们都是gpt3的模型，就自身使用感受来看，表现最好的还是davinci，它的速度也是最慢的，ada基本不能用，curie和babbage偶尔能用，不过有的时候连语法错误都修改不了，翻译也是各种不通顺。

2.代码

2.1.准备工作

采用添加宏的方式，首先要添加开发者选项卡。

这也不是必须的，因为可以通过快捷键alt f11直接打开vba的界面。

如果只为当前的文本添加宏，就在当前的project下添加模块，如果是为所有的word文档添加宏的话，就在normal中添加。之后插入模块，就可以添加vba的代码了。

其次，为了保证之后的代码正常运行，需要添加程序需要用的几个reference，它们的意思有点类似于r的library。不同的模块可以有不同的reference，可以选择项目后统一添加。

再次，由于vb处理起api的信息就很麻烦，这里需要单独载入两个文件，主要是jsonconverter，它能将api返回的文本转化为dictionary的形式方便提取。如果对正则表达熟悉的话，完全不需要使用jsonconverter就可获取到所需信息。 

这里通过导入文件的形式，将下载到的bas文件导入。另外要注意的是需要使用这个版本的vba-json-2.3.0，否则会报错。另外dictionary定义了几个对象的属性，也需要导入。

2.2. 调用api

callopenai，该函数会将word中选取的文字，加上你自己写的指示，一并提交给openai的模型，函数返回值response是一个dictionary，包括了model, choices, usage, created等各种字段。

model的选择和名称见上文。

prompt可以是任何指示，比如帮我修改这段文字。(变量名用instruction更合理)。

selectedtext是word文档中选取的文字。

function callopenai(model as string, prompt as string, selectedtext as string) as dictionary
    dim url as string
    dim headers as object
    dim body as object
    dim client as object
    dim response as object
 
    ' set up the api endpoint url, headers, and request body
    url = "https://api.openai.com/v1/completions"
    set headers = createobject("scripting.dictionary")
    headers.add "content-type", "application/json"
    headers.add "authorization", "bearer "
    set body = createobject("scripting.dictionary")
    
    body.add "model", model
    body.add "prompt", prompt & "{" & selectedtext & "}"
    body.add "max_tokens", 1000
    ' send the api request and get the response
    set client = createobject("msxml2.xmlhttp")
    client.open "post", url, false
    for each key in headers.keys
        client.setrequestheader key, headers(key)
    next
    client.send jsonconverter.converttojson(body)
    
    'debug.print client.responsetext
    ' parse the response json and return the completed text
    set response = jsonconverter.parsejson(client.responsetext)
    set callopenai = response
    
end function

这里需要在header变量中添加自己的openai的api-key，具体而言是在12行将 替换为自己的api_key。

此外，body变量可以添加而外的模型参数比如n, temperature等控制结果的输出，具体见api文档。

2.3.提取信息

一众函数分别从response的以下字段提取相应信息。

"model"-模型名称

'usage"-模型使用情况，用了多少个token

”choices"-模型返回的文字信息，这就是chatgpt的回答。

function getmodel(response as dictionary) as string
getmodel = response("model")
end function
 
 
function getusage(response as dictionary) as integer
getusage = response("usage")("total_tokens")
end function
 
 
function getresponsetext(response as dictionary) as string
dim resp as string
resp = response("choices")(1)("text")
resp = trim(resp)
    resp = replace(resp, vbnewline, "")
    'resp = replace(resp, "\n\n", "")
    'resp = replace(resp, vblf, "")
    'resp = replace(resp, vbcrlf, "")
    'resp = replace(resp, chr(10), "")
    'resp = replace(resp, chr(13), "")
    'resp = replace(resp, vbcr, "")
    'resp = replace(resp, vblf, "")
getresponsetext = resp
end function

dictornay的变量中，字典的字典是无法直接获取的，大部分操作都可能会报错，用debug.print也无法显示。比如choices下包括了一个字典，就需要使用类似的方式获取：response("choices")(1)("text")

2.4.计算模型使用费用

有必要根据模型的名称和使用量，计算一下使用成本。

function getestimatedfee(model as string, totaltokens as integer) as double
    ' set the token prices for each model
    dim tokenprices as object
    set tokenprices = createobject("scripting.dictionary")
    tokenprices.add "text-davinci-003", 0.02
    tokenprices.add "text-curie-001", 0.002
    tokenprices.add "text-babbage-001", 0.0005
    
    ' calculate the estimated fee
    dim tokenprice as double
    if tokenprices.exists(model) then
        tokenprice = tokenprices(model)
    else
        'defaultto the davinci token price if the modelisnot recognized
        tokenprice = tokenprices("text-davinci-003")
    end if
    getestimatedfee = totaltokens * tokenprice * 0.001
end function

2.5.返回信息到word界面

该部分代码的输入为，提取到文本(也就是chatgpt给你的答案)，费用以及模式。

这里考虑了三种模式：

第一种，track, 是将文本使用修订的方式放到word中，事实证明并不好用，会将所选文字删除并加上提取的文本。并不是哪里不同修订哪里。

第二种, append, 是在所选文字后面加入提取的文本，并以蓝色标注。

第三种, replace, 是直接替换所选文本。

另外，使用量以及费用会以对话框的形式出现。

sub processchatgptresponse(responsetext as string, feetext as string, mode as string)
 
 
    dim newrange as range
    dim resp as string
    resp = responsetext
    'resp = responsetext & "**" & feetext
    ' get the current selection
    dim currentselection as range
    set currentselection = selection.range
    
    ' determine how to handle the corrected text based on the mode parameter
    if mode = "track" then
        ' create a new range and insert the corrected text
        set newrange = activedocument.range(currentselection.end, currentselection.end)
        newrange.text = resp
        ' track changes on the new range
        activedocument.trackrevisions = true
        currentselection.text = resp
        activedocument.trackrevisions = false
    elseif mode = "append" then
        dim inserttext as string
        inserttext = vbcr & resp
        ' insert the corrected text in a new paragraph after the selection
        currentselection.insertafter inserttext
        '~~> remove selection. this will move the cursor at end of selected word
        selection.moveright unit:=wdcharacter, count:=1
        '~~> select the inserted word
        selection.moveright unit:=wdcharacter, count:=len(inserttext), extend:=wdextend
        selection.font.color = wdcolorblue
    elseif mode = "replace" then
        ' replace the selected text with the corrected text
        currentselection.text = resp
    end if
    msgbox "estimated cost:" & vbcrlf & feetext, vbinformation, "estimated cost"
    
end sub

3.界面

由于不同的按钮，目前只是用户的指示不同，剩下内容均一致，所以这里创建了一个函数，简化后面的流程。输入是model和prompt。这里统一使用了"append"的显示方式，即在选取文字之后添加chatgpt回答。

sub rinbbonfun(model as string, prompt as string)
    dim selectedtext as string
    dim response as dictionary
    dim modelname as string
    dim tokenn as integer
    dim feetext as string
    dim responsetext as string
    selectedtext = selection.text
    set response = callopenai(model, prompt, selectedtext)
    responsetext = getresponsetext(response)
    modelname = getmodel(response)
    tokenn = getusage(response)
    estimatedfee = getestimatedfee(modelname, tokenn)
    feetext = "model: " & modelname & ", estimated cost: $" & estimatedfee & "(tokens:" & tokenn & ")"
    'debug.print responsetext
    ' do something with the response, such as replace the selection with the returned text
    processchatgptresponse responsetext, feetext, "append"
    
end sub

建立相应的函数，用于不同的按钮。

sub improveemail()
rinbbonfun "text-davinci-003", "improve my writing in the email:"
end sub
sub rewordit()
rinbbonfun "text-davinci-003", "rephrase the following texts and avoid plagiarism:"
end sub
sub summarizeit()
rinbbonfun "text-davinci-003", "summarize the following texts for me:"
end sub
sub translate2cn()
rinbbonfun "text-davinci-003", "translate the following texts into simplified chinese:"
end sub
sub translate2en()
rinbbonfun "text-davinci-003", "translate the following texts into english:"
end sub
sub improvewriting()
rinbbonfun "text-davinci-003", "improve my writing:"
end sub
sub elaborateit()
rinbbonfun "text-davinci-003", "elaborate the following content:"
end sub

然后在ribbon选项中将这些宏添加成按钮。

修改名称和图标即可。

4.实际使用效果

找了一个改错题，选取整段文字，点击按钮，返回修改好的文字，以及使用信息。

之后用修改过的文字，测试其他按键。

至此，基本功能实现。其他的一些功能，比如使用下拉菜单选择想要的模型，添加输入框录入使用组的api-key，添加自定义的按钮图案等功能，需要通过xml定制ribbon内容，就不浪费时间了。